編按：

一說(shuō)到多條件求和問(wèn)題，大家首先想到的就是SUMIF函數(shù)和SUMIFS函數(shù)。兩個(gè)函數(shù)都是處理此類問(wèn)題的強(qiáng)者，但不管是書寫方式、應(yīng)用方法還是各自優(yōu)勢(shì)，都有極大的不同……

如果需要按照多個(gè)條件進(jìn)行求和，就要用到SUMIFS函數(shù)，與SUMIF函數(shù)不同之處在于，SUMIFS的第一參數(shù)是求和區(qū)域，后面的參數(shù)兩兩一組，條件區(qū)域在前，條件在后，函數(shù)的結(jié)構(gòu)為：

SUMIFS(求和區(qū)域,條件區(qū)域1,條件1, 條件區(qū)域2,條件2,……)

但是在實(shí)際應(yīng)用中，大家往往會(huì)分不清多條件和多條件的區(qū)別，下面用一個(gè)數(shù)據(jù)源來(lái)舉例，分別提兩個(gè)問(wèn)題。

問(wèn)題1：夏淼銷售了多少臺(tái)雙門冰箱？

問(wèn)題2：雙門冰箱和液晶電視一共賣了多少臺(tái)？

思考：請(qǐng)問(wèn)這兩個(gè)問(wèn)題都是多條件求和嗎？都能用SUMIFS統(tǒng)計(jì)嗎？

有興趣的朋友可以自己先試試。

其實(shí)，這兩個(gè)問(wèn)題都可以算是多條件，但是又不完全一樣。

問(wèn)題1：涉及到兩組條件，分別是姓名和商品名稱，每一組條件都有一個(gè)具體的值。

問(wèn)題2：只涉及一組條件，但是條件有兩個(gè)值。

當(dāng)問(wèn)題存在多組條件的時(shí)候，就能用SUMIFS；當(dāng)問(wèn)題只有一組條件的時(shí)候，就得用SUMIF。如果條件存在多個(gè)值的時(shí)候，還需要用SUM做合計(jì)。

這就是今天要和大家分享的核心內(nèi)容，下面通過(guò)幾個(gè)例子，讓大家能理解這些很讓人迷糊的問(wèn)題。

兩組條件且每組條件只有一個(gè)值

問(wèn)題：沈伊杰銷售的壁掛空調(diào)數(shù)量合計(jì)

公式為=SUMIFS(D:D,B:B,"沈伊杰",C:C,"壁掛空調(diào)")

在這個(gè)問(wèn)題中，求和列是D列，有兩組條件，第一組條件是姓名（B列），條件是"沈伊杰"，第二組條件是商品名稱（C列），條件是"壁掛空調(diào)"，按照標(biāo)準(zhǔn)的SUMIFS格式使用就好了。

兩組條件且每組條件只有一個(gè)值（使用通配符）

問(wèn)題：張珂銷售的洗衣機(jī)數(shù)量合計(jì)

公式為=SUMIFS(D:D,B:B,"張珂",C:C,"*洗衣機(jī)")

這個(gè)問(wèn)題和上面的問(wèn)題類似，區(qū)別是第二個(gè)條件用到了通配符。

關(guān)于通配符的用法，可以參考前一篇教程。

通過(guò)以上示例，需要掌握SUMIFS的幾個(gè)特點(diǎn)：

1.不能與SUMIF混淆求和區(qū)域的位置。

2.SUMIFS不能省略任何一個(gè)參數(shù)。

3.SUMIFS的條件中可以使用通配符。

4.只用一組條件時(shí)，SUMIFS可以取代SUMIF。

5.條件中含有非數(shù)字的內(nèi)容時(shí)，需要加引號(hào)，這一點(diǎn)與SUMIF一致。

一組條件但有兩個(gè)值

問(wèn)題：夏淼與張珂的銷量合計(jì)

公式1：=SUMIF(B:B,"夏淼",D:D)+SUMIF(B:B,"張珂",D:D)

這個(gè)問(wèn)題，只用到一組條件姓名（B列），但是具體的條件有兩個(gè)值?？梢杂脙蓚€(gè)SUMIF統(tǒng)計(jì)后再相加，也可以用SUM和SUMIF函數(shù)組合進(jìn)行統(tǒng)計(jì)。

公式2：=SUM(SUMIF(B:B,{"夏淼","張珂"},D:D))

公式2中，SUMIF的第二參數(shù)使用了常量數(shù)組{"夏淼","張珂"}，表示分別計(jì)算出夏淼與張珂的銷量，再使用SUM函數(shù)將兩人的銷售求和，與公式1結(jié)果相同，使用SUM的公式明顯簡(jiǎn)潔了許多。

公式2的好處在于當(dāng)條件的組成部分增加后，使用了SUM函數(shù)的公式更加易于編寫和理解，只需要在常量數(shù)組中增加具體的條件值即可。

到這里，以上三個(gè)例子解釋了多組條件和多值條件的區(qū)別，相信大家都能理解。

擴(kuò)展延伸：

在多條件求和中，大家可以發(fā)現(xiàn)常量數(shù)組多次出現(xiàn)在多值條件統(tǒng)計(jì)中。其實(shí)，在實(shí)際工作中，有效地使用常量數(shù)組會(huì)讓大家更輕松地處理更多復(fù)雜的統(tǒng)計(jì)問(wèn)題，比如下面三種情況：

案例一

問(wèn)題1：夏淼與張珂銷售的洗衣機(jī)合計(jì)

公式為=SUM(SUMIFS(D:D,C:C,"*洗衣機(jī)",B:B,{"夏淼","張珂"}))

公式中存在兩組條件（品名和銷售人員姓名），并且在品名中使用了通配符，表示分別統(tǒng)計(jì)出夏淼和張珂銷售的洗衣機(jī)數(shù)量后再用SUM求和。

案例二

問(wèn)題2：夏淼與張珂銷售的洗衣機(jī)與冰箱合計(jì)

公式為=SUM(SUMIFS(D:D,C:C,{"*洗衣機(jī)","*冰箱"},B:B,{"夏淼";"張珂"}))

這個(gè)公式中，品名用了逗號(hào)分隔常量數(shù)組{"*洗衣機(jī)","*冰箱"}，銷售人員用了分號(hào)分隔常量數(shù)組{"夏淼";"張珂"}。因此會(huì)得到四個(gè)數(shù)據(jù)，分別表示夏淼銷售的洗衣機(jī)、張珂銷售的洗衣機(jī)、夏淼銷售的冰箱和張珂銷售的冰箱，再用SUM求和得到最終結(jié)果。

案例三

問(wèn)題3：夏淼銷售的洗衣機(jī)與張珂銷售的冰箱合計(jì)

公式為=SUM(SUMIFS(D:D,C:C,{"*洗衣機(jī)","*冰箱"},B:B,{"夏淼","張珂"}))

這個(gè)公式中兩個(gè)數(shù)組都用的逗號(hào)，這樣只會(huì)得到兩個(gè)數(shù)據(jù)，分別表示夏淼銷售的洗衣機(jī)和張珂銷售的冰箱。

最后這三個(gè)問(wèn)題，本質(zhì)是用到了數(shù)組的計(jì)算原理，尤其是逗號(hào)和分號(hào)帶來(lái)的不同效果，對(duì)于這個(gè)話題有興趣的小伙伴可以掃描下方二維碼，到公眾號(hào)中留言，咱們單獨(dú)分享一篇教程。

本文配套的練習(xí)課件請(qǐng)加入QQ群：902294808下載。

做Excel高手，快速提升工作效率，部落窩教育《一周Excel直通車》視頻和《Excel極速貫通班》直播課全心為你！

掃下方二維碼關(guān)注公眾號(hào)，可隨時(shí)隨地學(xué)習(xí)Excel：

相關(guān)推薦：

無(wú)往而不利的SUMIF面對(duì)這種條件求和竟然傻眼了！

Excel教程：sumifs函數(shù)常量數(shù)組簡(jiǎn)化公式

sumif和countif函數(shù)應(yīng)用

SUMIF怎么使用通配符進(jìn)行模糊查找

版權(quán)申明：

本文作者老菜鳥；同時(shí)部落窩教育享有專有使用權(quán)。若需轉(zhuǎn)載請(qǐng)聯(lián)系部落窩教育。