編按：

今天來(lái)給大家歸納整理查找類(lèi)公式，涉及5個(gè)函數(shù)，20+個(gè)函數(shù)公式，一起來(lái)看看吧！

Excel里常用的查找函數(shù)有五個(gè)：VLOOKUP、INDEX、OFFSET、LOOKUP、INDIRECT。

能夠用到查找函數(shù)的場(chǎng)景大致可以分成四類(lèi)：?jiǎn)螚l件查找、多條件查找、一對(duì)多查找、多對(duì)多查找。

今天為大家整理一期查找公式大全，篇幅所限，不做具體解釋了，遇到對(duì)應(yīng)的情況直接挑合適的公式即可。

一、單條件查找（從左向右查找）

例如，要找到指定訂單ID所對(duì)應(yīng)的地址，首選公式為=VLOOKUP(D3,A:B,2,0)。

使用其他查找函數(shù)的公式分別為：

=INDEX(B:B,MATCH(D3,A:A,0))

=OFFSET($B$1,MATCH(D3,A:A,0)-1,)

=LOOKUP(1,0/(A:A=D3),B:B)

=INDIRECT("B"&MATCH(D3,A:A,))

說(shuō)明：雖然五個(gè)公式可以得到同樣的結(jié)果，但具體原理各有不同。解決這類(lèi)問(wèn)題大家可能更習(xí)慣用VLOOKUP，但是VLOOKUP有個(gè)最大的限制就是查找條件必須在查找區(qū)域的首列，也就是從左向右查找。如果是從右向左又該如何做呢？看下面這個(gè)例子。

二、單條件查找（從右向左查找）

例如按照指定的地址查找對(duì)應(yīng)的訂單ID，上述五個(gè)公式都需要做修改。

公式分別為：

=VLOOKUP(D3,IF({1,0},B:B,A:A),2,0)

=INDEX(A:A,MATCH(D3,B:B,0))

=OFFSET($A$1,MATCH(D3,B:B,0)-1,)

=LOOKUP(1,0/(B:B=D3),A:A)

=INDIRECT("a"&MATCH(D3,B:B,))

大家對(duì)比一下就會(huì)發(fā)現(xiàn)，只有VLOOKUP的變化是最大的，用IF函數(shù)構(gòu)建了一個(gè)數(shù)組，而其他四個(gè)公式基本一樣。

除了以上說(shuō)的兩種單條件查找，日常用得比較多的還有多條件查找。

三、多條件查找

例如通過(guò)客戶(hù)ID和商品名稱(chēng)兩個(gè)條件來(lái)查找運(yùn)貨商，還是用上述五個(gè)查找函數(shù)來(lái)對(duì)比看下公式。

公式分別為：

=VLOOKUP(E3&F3,IF({1,0},A:A&B:B,C:C),2,0)

=INDEX(C:C,MATCH(E3&F3,A:A&B:B,0))

=OFFSET($C$1,MATCH(E3&F3,A:A&B:B,0)-1,)

=LOOKUP(1,0/((A:A=E3)*(B:B=F3)),C:C)

=INDIRECT("c"&MATCH(E3&F3,A:A&B:B,))

說(shuō)明：多條件查找時(shí)，除了LOOKUP的原理不同之外，其他四個(gè)函數(shù)都是利用了&將條件進(jìn)行合并，其本質(zhì)與單條件并無(wú)不同，但是由于合并過(guò)程中涉及到了數(shù)組計(jì)算，非365版本的用戶(hù)在使用時(shí)需要按Ctrl、shift和回車(chē)鍵輸入公式。另外強(qiáng)調(diào)一點(diǎn)，多條件查找時(shí)不建議使用整列，不然你的表格會(huì)很卡。

注意：以上的單條件查找和多條件查找，返回的結(jié)果都是唯一的，如果返回結(jié)果是多項(xiàng)的話(huà)，對(duì)應(yīng)的問(wèn)題就變成了一對(duì)多查找和多對(duì)多查找。

這兩類(lèi)問(wèn)題使用公式解決都比較麻煩，當(dāng)然如果你用的是最新版Excel的話(huà)，可以用新版特有的函數(shù)去處理，下面還是分情況來(lái)進(jìn)行介紹。

四、一對(duì)多查找

例如要查找出指定運(yùn)貨商的所有訂單ID，就需要用到一對(duì)多查找的公式，非365版本可以使用公式：

=IFERROR(INDEX($B$2:$B$19,SMALL(IF($A$2:$A$19=$D$2,ROW($1:$18),99),ROW(A1))),"")

結(jié)果如圖所示。

如果你使用的是365版本的Excel，這個(gè)問(wèn)題就比較容易了，直接使用公式=FILTER($B$2:$B$19,$A$2:$A$19=G2)即可，結(jié)果如圖所示。

以上是一對(duì)多的兩個(gè)公式，多對(duì)多的公式就更復(fù)雜了。

五、多對(duì)多查找

按照城市和運(yùn)貨商查找對(duì)應(yīng)的訂單ID，非365版本使用公式：

=IFERROR(INDEX($C$2:$C$19,SMALL(IF($A$2:$A$19&$B$2:$B$19=$E$2&$F$2,ROW($1:$18),99),ROW(B1))),"")

365版本使用公式=FILTER($C$2:$C$19,($A$2:$A$19=$E$2)*($B$2:$B$19=F2))

以上就是今天分享的內(nèi)容，是不是感覺(jué)有些函數(shù)的用法還沒(méi)有完全掌握呢？

關(guān)注我們，一步一步慢慢來(lái)吧！

希望最后大家都能夠了解各種查找函數(shù)在不同場(chǎng)景的使用方法。

本文配套的練習(xí)課件請(qǐng)加入QQ群：902294808下載。

做Excel高手，快速提升工作效率，部落窩教育《一周Excel直通車(chē)》視頻和《Excel極速貫通班》直播課全心為你！

掃下方二維碼關(guān)注公眾號(hào)，可隨時(shí)隨地學(xué)習(xí)Excel：

相關(guān)推薦：

八大查找函數(shù)公式，輕松搞定數(shù)據(jù)中的多條件查找

10種職場(chǎng)人最常用的excel多條件查找方法?。ńㄗh收藏）

Excel教程：如何制作帶有層次和透視感的圖表？

八大查找函數(shù)公式，輕松搞定數(shù)據(jù)中的多條件查找

版權(quán)申明：

本文作者老菜鳥(niǎo)；同時(shí)部落窩教育享有專(zhuān)有使用權(quán)。若需轉(zhuǎn)載請(qǐng)聯(lián)系部落窩教育。